WMI?VBScript?

Ne folosim de un exemplu de script de pe “Hey! Scripting guy!” care ne ajuta sa cautam in textul dintr-un event si de modelul de script descris in articolul de aici.

In prima etapa scriptul monitorizeaza aparitia oricarui eveniment cu ID-ul 641

Set colMonitoredEvents = objWMIService.ExecNotificationQuery _   
    ("Select * from __InstanceCreationEvent Where " _
        & "TargetInstance ISA ‘Win32_NTLogEvent’ " _
            & "and TargetInstance.EventCode = ’641′ ")

Urmand ca apoi sa caute un corpul mesajului textul “domain admins”.

If InStr(LCase(objLatestEvent.TargetInstance.Message), "domain admins") Then
    Wscript.Echo "Message: " & objLatestEvent.TargetInstance.Message
End If

Intreg scriptul il gasiti mai jos:

strComputer = "."

Set objWMIService = GetObject("winmgmts:{(Security)}\\" & _
        strComputer & "\root\cimv2")

Set colMonitoredEvents = objWMIService.ExecNotificationQuery _   
    ("Select * from __InstanceCreationEvent Where " _
        & "TargetInstance ISA ‘Win32_NTLogEvent’ " _
            & "and TargetInstance.EventCode = ’641′ ")

Do
    Set objLatestEvent = colMonitoredEvents.NextEvent
    If InStr(LCase(objLatestEvent.TargetInstance.Message), "domain admins") Then
        Wscript.Echo "Message: " & objLatestEvent.TargetInstance.Message
    End If

Loop

 

Iata ce se intampla cand il rulam si modificam grupul Domain Admins.

Ca actiune in cazul modificarii unui event doar afisam un text in cazul scriptului de mai sus, insa actiunea potrivita ar fi generarea si trimiterea unui email pentru a avertiza administratorul (dar asta alta data).

Pentru o mai buna protectie e bine sa monitorizam si grupurile Administrators, Enterprise Admins, Schema Admins (chiar si Backup & Server Operators ar fi bine).

Exista destul de multe metode pentru a monitoriza aparitia unui anumit eveniment in event viewer. Avem tool-uri, scripturi, agenti de monitorizare, iar de la Windows Vista in sus putem sa declansam anumite activitati la aparitia unui eveniment folosind Task Scheduler.

Astazi o sa prezint un mod de a face acest lucru folosind un script VBS (asta si pentru ca poate fi folosit cam pe orice versiune de Windows):

strComputer = “.”

Set objWMIService = GetObject(“winmgmts:{(Security)}\\” & _
        strComputer & “\root\cimv2″)

Set colMonitoredEvents = objWMIService.ExecNotificationQuery _  �
    (“Select * from __InstanceCreationEvent Where ” _
        & “TargetInstance ISA ‘Win32_NTLogEvent’ ” _
            & “and TargetInstance.EventCode = ’7035′ “)

Do
    Set objLatestEvent = colMonitoredEvents.NextEvent
        Wscript.Echo “Un serviciu a fost oprit”
        Wscript.Echo “————————”
        Wscript.Echo “User: ” & objLatestEvent.TargetInstance.User
        Wscript.Echo “Time: ” & objLatestEvent.TargetInstance.TimeWritten
        Wscript.Echo “Category: ” & objLatestEvent.TargetInstance.Category
        Wscript.Echo “Event Code: ” & objLatestEvent.TargetInstance.EventCode
        Wscript.Echo “Message: ” & objLatestEvent.TargetInstance.Message
        Wscript.Echo “Record Number: ” & objLatestEvent.TargetInstance.RecordNumber
        Wscript.Echo “Source Name: ” & objLatestEvent.TargetInstance.SourceName
        Wscript.Echo “Event Type: ” & objLatestEvent.TargetInstance.Type
        Wscript.Echo

        Wscript.Echo objLatestEvent.TargetInstance.Message
        Wscript.Echo
Loop

Scriptul monitorizeaza aparitia evenimentului cu ID-ul 7035 (vedeti linia cu TargetInstance.EventCode = ’7035′; pentru a monitoriza alt event modificati aceasta linie) in oricare din logurile sistemului. In momentul in care apare va afisa detalii despre eveniment. ID-ul 7035 apare la oprirea sau pornirea unui serviciu in Windows. Evenimentele de start si stop au acelasi cod (7035 si 7036) asa ca e putin mai greu sa deosebesti intre oprirea si pornirea unui serviciu doar din ID-ul eventului. Ca exemplu l-am pornit pe un server din command prompt:

Si am restartat serviciul DNS Client:

La cateva secunde iata ce se intampla in command prompt:

Exemplul cu restartul de serviciu nu este cel mai bun exemplu tocmai pentru ca nu exista event-uri separate pentru start si stop, insa e suficient ca sa intelegeti ca functioneaza. Scriptul poate fi modificat foarte usor pentru a face altceva, nu numai a afisa informatii pe ecran. Trebuie doar sa introduceti codul in bucla Do … Loop din script.

Sursa: Hey, Scripting Guy!

Scopul scriptului care il voi prezenta mai jos este de a cauta in Active Directory dupa delegarile facute la nivel de Organizational Unit-uri. Intr-un domeniu in care facem delegari pentru alti admini, daca acestea nu sunt documentate si sunt facute folosind useri si nu de grupuri, in timp sunt uitate iar userul va avea acces in continuare la resursele delegate chiar daca nu face parte din grupurile de administratori.

Scriptul arata cam asa:

‘Script created by Andrei Ungureanu
‘www.winadmin.ro

On error resume next
Const ADS_SCOPE_SUBTREE = 2
Const ADS_ACEFLAG_INHERITED_ACE = &H10

Set objConnection = CreateObject("ADODB.Connection")
Set objCommand =   CreateObject("ADODB.Command")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"

Set objCOmmand.ActiveConnection = objConnection
objCommand.CommandText = _
    "Select Name, distinguishedName from ‘LDAP://DC=itboard,DC=local’ " _
        & "Where objectClass=’organizationalUnit’" 
objCommand.Properties("Page Size") = 1000
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
Set objRecordSet = objCommand.Execute
objRecordSet.MoveFirst

Do Until objRecordSet.EOF
        strOU = objRecordSet.Fields("distinguishedName") 
Set ObjUser = GetObject("LDAP://" & strOU)
Set objsd = objUser.Get("ntSecurityDescriptor")
Set dacl = objsd.DiscretionaryAcl

For Each ace In dacl
If ace.Trustee = "ITBOARD\andreiu" Then
    iAceFlags = ace.AceFlags

        If(iAceFlags And ADS_ACEFLAG_INHERITED_ACE)Then
         Exit For
        End If

    wscript.echo strOU
    Exit For
End If
next

    objRecordSet.MoveNext
Loop

E nevoie sa inlocuiti in script ITBOARD\andreiu cu userul pe care il cautati si la fel numele domeniului din dc=itboard,dc=local in numele domeniului pe care rulati scriptul. Scriptul va verifica toata ierarhia de OU-uri si va afisa doar locatiile in care userul are permisiuni (daca exista deja permisiuni mostenite de la un OU parinte nu va mai verifica alte permisiuni pe acel OU).

Atentie ca numele userului si domeniul sunt case sensitive. Acestea trebuie puse in script exact asa cum apar in proprietatile userului:

Scriptul nu este bullet proof si e posibila sa existe cazuri in care sa nu detecteze tot. Pentru a-i imbunatati viteza am decis sa fac skip la OU-urile unde exista deja drepturi mostenite pentru acel user.

PS: Atentie ca scripturile postate aici sunt modificate de wordpress si anumite caractere trebuie modificate de mana cand faceti copy/paste la script.

Stiu ca foarte multi administratori de Active Directory s-au lovit de problema asta. In special cand preiei administrarea unui domeniu de la altcineva sau cand obiectele care le ai in domeniul tau au venit printr-o migrare.

Bifa din imaginea de mai jos se refera la mostenirea permisiunilor de pe containerul care contine obiectul (sau pot fi mai multe nu numai unul).

E nevoie ca aceste permisiuni sa se propage la obiectele din container, pentru ca la nivel de container se fac delegarile de permisiuni. Sa luam exemplul in care delegam permisiunea de a reseta parole unui admin regional pentru toti userii care se afla intr-o anumita locatie, mai exact toti userii care se afla intr-un anumit container (OU).

Daca obiectele din containerul meu nu au bifa de care pomeneam mai sus activa, delegarea nu o sa functioneze. By default bifa e activa, insa pe parcursul vietii unui obiect in AD, se poate schimba. Cateodata poate fi facuta manual sau de anumite procese – gen cazul cand un user este adaugat in grupul Domain Admins, iar cand este scos nu este pusa la loc.

Cum putem sa fortam activarea acestei bife sau sa vedem daca este activa? In cazul unui singur utilizator e simplu, problema apare atunci cand avem zeci sau sute de utilizatori (poate chiar mai multi dar ne oprim aici) de modificat sau verificat.

Ca de obicei VBScript ne sare in ajutor. Mai jos avem un exemplu de script care verifica toti userii dintr-un anumit OU din AD si activeaza optiunea Allow inheritable permissions.

‘Script created by Andrei Ungureanu
‘www.winadmin.ro

On Error Resume Next

Const ADS_SCOPE_SUBTREE = 2
Const SE_DACL_PROTECTED = 0

Set objConnection = CreateObject("ADODB.Connection")
Set objCommand =   CreateObject("ADODB.Command")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"
Set objCommand.ActiveConnection = objConnection

objCommand.Properties("Size Limit")= 10000

objCommand.Properties("Page Size") = 10000
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE

objCommand.CommandText = _
"<LDAP://ou=accounts,dc=itboard,dc=local>;"_
& "(objectCategory=user);sAMAccountName,distinguishedname;subtree"

Set objRecordSet = objCommand.Execute

objRecordSet.MoveFirst
Do Until objRecordSet.EOF

userDN = objRecordSet.Fields("distinguishedName").Value
set objObject = getobject("LDAP://" & userDN & "")
Set objntSD = objObject.Get("nTSecurityDescriptor")

intNTSDControl = objNtSD.Control

If intNTSDControl <> 35844 Then
    ‘ Enable "allow inheritable permissions".
    intNTSDControl = intNTSDControl And SE_DACL_PROTECTED
    objntSD.Control = intNTSDControl
    objObject.Put "nTSecurityDescriptor", objntSD
    objObject.SetInfo
    WScript.Echo "Obiectul " & userDN & " a fost modificat"
End If

objRecordSet.MoveNext
Loop

Calea LDAP://ou=accounts,dc=itboard,dc=local trebuie inlocuita cu locatia in care avem obiectele ce trebuiesc scanate. Merge specificat chiar si domain root insa nu recomand asa ceva. Recomand ca inainte sa folositi scriptul, sa il verificati pe un mediu de test.

PS: scriptul merge modificat foarte usor si doar pentru a arata starea bifei Allow inheritable permissions.

Ca sa dam cateva exemple  :

- Sesiune de RDP catre statia respectiva (dupa validare suntem intrebati daca vrem (sau nu) sa deconectam userul).

- Query WMI pe statie.

- Diverse tool-uri third party

-Scripturi In-house

M-am tot gandit in ultima vreme la o metoda mai eleganta de a centraliza aceste informatii. Am tot analizat acest proces si de la un sheet in excel am ajuns la concluzia ca ar fi mai util sa fie in AD, mai ales ca fiecare dintre noi il foloseste mai tot timpul. Asa ca m-am gandit ca ar fi bine sa fac un script.

Acest script va verifica din sesiunea locala variabilele de sistem %username% si %computername% iar daca ele sunt identice cu cele din AD (aici ma refer la common name-ul asociat obiectelor) atunci va modifica attributul description pentru obiectul aferent statiei cu un string formatat din script.

Acesta se va aplica la user logon printr-un GPO, sau setat ca logon script din Active Directory User and Computers in tabul profile.

Inainte de a incepe cu analiza scriptului voi sublinia pasi logici de implementare:

1. Script

2. Modificarea securitatii pe OU-ul care contine statiile.

3. Creare GPO, sau setat ca logon script din Active Directory User and Computers in tabul profile.

4. Testare

5. Aplicare politica

In acest articol voi prezenta doar pasii 1 si 2.

1. Script

Codul scriptului este colorat in gri pentru o preluare mai rapida in pagina.

‘Created by Mihai Marius 2009
‘

Set wshShell = WScript.CreateObject( “WScript.Shell” )
Local_ComputerName = wshShell.ExpandEnvironmentStrings( “%COMPUTERNAME%” )
Local_UserName = wshShell.ExpandEnvironmentStrings( “%USERNAME%” )

Set objSysInfo = CreateObject( “ADSystemInfo” )
AD_ComputerName = objSysInfo.ComputerName
AD_UserName = objSysInfo.UserName

Set objUser = GetObject(“LDAP://” & AD_UserName)
Set objComputer = GetObject(“LDAP://” & AD_ComputerName)

    If Local_UserName = objUser.CN and Local_ComputerName = objComputer.CN Then

Text_Desc = “Userul ” & objUser.CN & ” s-a connectat  la ” & Now & “.”

objComputer.Description = Text_Desc
objComputer.SetInfo

Set wshShell = Nothing
Set objSysInfo = Nothing
Set objComputer    = Nothing
Set objUser = Nothing

Else

Set wshShell = Nothing
Set objSysInfo = Nothing
Set objComputer    = Nothing
Set objUser = Nothing

    End If

WScript.Quit

Acum sa analizam codul si sa oferim cateva informatii.

Set wshShell = WScript.CreateObject( “WScript.Shell” )
Local_ComputerName = wshShell.ExpandEnvironmentStrings( “%COMPUTERNAME%” )
Local_UserName = wshShell.ExpandEnvironmentStrings( “%USERNAME%” )

Initializam un shell pentru sesiunea locala de unde extragem variabilele de sistem %computername% si %username%.

Valorile returnate vor fi declarate ca Local_ComputerName  si Local_UserName.

Set objSysInfo = CreateObject( “ADSystemInfo” )
AD_ComputerName = objSysInfo.ComputerName
AD_UserName = objSysInfo.UserName

Cream o instanta a clasei ADSystemInfo, pentru a utiliza obiectele din AD care fac referinta la statie si utilizator. Este important de subliniat valoarea acestei clase deoarece ea ne returneaza DN-ul (distinguished name) obiectelor util in pasul urmator.

Set objUser = GetObject(“LDAP://” & AD_UserName)
Set objComputer = GetObject(“LDAP://” & AD_ComputerName)

Query LDAP pentru a utiliza atributele din AD asociate statiei si utilizatorului.

If Local_UserName = objUser.CN and Local_ComputerName = objComputer.CN Then

Text_Desc = “Userul ” & objUser.CN & ” s-a connectat  la ” & Now & “.”

O functie de validare intre valorile locale si valorile asociate obiectelor in AD. M-am gandit sa fac un double check ale acestor valori pentru a nu modifica campul description daca nu ele nu sunt identice.

Daca valorile sunt egale atunci se formateaza textul pentru descriere. Intial m-am gandit sa trec doar utilizatorul dar am vazut pe net si alte abordari de forma: “Userul x s-a logat la data z ora y” si m-am gandit ca acesta abordare ar fi mai utila pentru debugging.

objComputer.Description = Text_Desc
objComputer.SetInfo

Set wshShell = Nothing
Set objSysInfo = Nothing
Set objComputer    = Nothing
Set objUser = Nothing

Setam textul formatat pentru atributul description al obiectului ce reprezinta statia. Eliminam obiectele care au fost incarcate in memoria sistemului .

Else

Set wshShell = Nothing
Set objSysInfo = Nothing
Set objComputer    = Nothing
Set objUser = Nothing

    End If
WScript.Quit

Daca valorile nu sunt egale atunci eliminam obiectele care au fost incarcate in memoria sistemului dupa care terminam functia si iesim din script.

2.Modificarea securitatii pe OU-ul care contine statiile.

In acest pas voi descrie modul in care putem modifica securitatea OU-ului in care se regasesc obiectele care fac referinta la statiile din domeniu, pentru a permite doar modificarea campului description.
Fara aceste permisiuni de modificare acest script nu va functiona pentru useri simpli (ma refer desigur la Domain Users).

In exemplul meu voi folosi  OU-ul Comp iar permisiunile le voi asocia groupului Domain Users. Ar fi de preferat sa utilizam un alt group ca sa nu-l folositi pe cel default, pentru a limita expunerile la eventuale atacuri.

Deschidem consola de Active Directory Users and Computers –> Selectam OU-ul Comp –> click dreapta Security si selectam Advanced –> Add –> Introducem Domain Users si selectam OK –> selectam tabul Properties.

In campul Apply onto selectam “Computer objects” si selectam Write Description.

Poza arata exact pasi enumerati mai sus.

Click OK, three times.

Dupa aplicarea scriptului in campul description al unei statii ar trebui sa arate asa:

Sfat: Inainte de aplicarea acestei politci ar fi bine sa faceti cateva teste pentru a nu perturba activitatea.

Troubleshooting: In cazul in care nu ati configurat corect , partea de permisiuni pe OU, veti primi un mesaj de eroare (pe sesiunea clientului) de forma :

Scriptul cu extensia ps1 se copiaza in folderul scripts asociat cu politica si se adauga cu Add, fara powershell.exe in fata.

Pe sistemul meu de test am avut setat deja Set-ExecutionPolicy Unrestricted. Dupa asta am setat sistemul si pe AllSigned si scriptul ruleaza fara probleme

Un exemplu pentru folosirea acestui script ar fi un subnet cu ip-uri puse static si unde trebuie sa schimbi adresa serverului de DNS la toate sistemele. Sau un sistem setat cu IP static pe care vrei sa-l treci pe DHCP. Hai sa vedem si cateva exemple.

Cand pentru numele calculatorului folosim “.” inseamna ca ne conectam la sistemul local. Scriptul urmator trece pe DHCP toate adaptoarele de retea care au TCP/IP activat:

strComputer = "."
set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * From Win32_NetworkAdapterConfiguration Where IPEnabled = 1")

For Each objItem in colItems
    If objItem.DHCPEnabled = False then
      errDHCP = objItem.EnableDHCP()

      errDNS = objItem.SetDNSServerSearchOrder() 
    End If
Next

Bun. Acum sa luam cazul in care vrem sa trecem de pe DHCP pe IP fix. Pentru asta folosim metoda EnableStatic care primeste 2 parametri IP Address si Subnet Mask sub forma:

errStaticIP = objItem.EnableStatic(array(“192.168.0.10”),array(”255.255.255.0”))

errDNS = objItem.SetDNSServerSearchOrder(array(“192.168.0.100, 192.168.0.101”)) 

Ce altceva mai putem sa setam? WINS de exemplu:

errWins = objItem.SetWINSServer (array(“192.168.0.100, 192.168.0.101”))

Pe scurt, puteti seta cam orice legat de configuratia TCP/IP prin script. Chiar si combinatii mai ciudate cu IP luat prin DHCP si DNS pus manual. Unul din scripturile facute in ultimul timp (pe genunchi) se conecta la toata sistemele dintr-un anumit subnet si imi dadea informatii despre clientul de DHCP: cand si-a luat IP ultima data, cand expira leaseul, de la ce server si-a luat IP, etc.

Concluzie: daca trebuie sa treceti o retea intreaga pe DHCP nu e nevoie sa vizitati fiecare calculator in parte. Merge si remote.

Pentru asta folosim colectia WScript.Arguments. Si putem verifica daca au fost specificati parametri folosing proprietatea Count:

arguments = WScript.Arguments.Count

Urmand a face si o verificare:

If arguments < 1 then
  WScript.Echo “Ati uitat sa specificati parametrii. Exemplu: cscript script.vbs [parametru]”
  WScript.Quit
end If

Daca se trece mai departe de conditia If putem sa citim parametrii:

param1 = WScript.Arguments.Item(0)

Wscript.Echo param1

Daca avem mai multi citim si celelalte obiecte din colectie ex:WScript.Arguments.Item(1) (ati prins ideea).

PS: by default scripturile sunt rulate folosind Wscript.exe atunci cand pornesti scriptul din Explorer. (comportamentul default merge modificat) Recomandat e sa rulati scripturile folosind Cscript.exe (ex: cscript myscript.vbs parametru) pentru a primi output-ul in fereastra din care ati lansat scriptul si pentru a-l putea redirecta.

Server1
Server2
Server3
Server4

Ideea e ca aveam nevoie de un script care se va conecta la toate sisteme din lista si va face ceva. Ce va face nu e important acum Important e cum citim lista cu serverele. Iata si scriptul:

Const ForReading = 1
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile("d:\temp\servers.txt", ForReading)
Do While objTextFile.AtEndOfStream <> True
strServer = objTextFile.ReadLine
Wscript.Echo "Server: " & strServer
Loop
objTextFile.Close

In linia Set objTextFile = objFSO.OpenTextFile("d:\temp\servers.txt", ForReading) puteti specifica locatia listei. Merge si ca parametru dar in alt post.

Iar in bucla Do While-Loop puteti introduce bucata de cod de care aveti nevoie si care se va folosi de variabila strServer.

In cazul meu ma interesau setarile ce tin de forwarder, dar hai sa vedem ce a iesit.

Prima data trebuie sa aflam care sunt serverele DC din domeniu. Pentru asta m-am inspirat dintr-un script de-al lui Richard Mueller care se conecteaza la configuration partion si cauta toate obiectele de tip NTDSA. Problema e ca noi trebuie sa cautam doar DC-urile, altfel as fi cautat simplu dupa server, dar e posibil gasesc si ceva servere Exchange care mai apar pe acolo. Cautand dupa NTDSA gasesc DC-urile insa trebuie sa aflu obiectul parinte, de asta am apelat la scriptul lui Richard Mueller ca sa nu ma mai chinui eu. Bineinteles ca exista si alte variante – gen enumerarea obiectelor din containerul Domain Controllers.

Dim objRootDSE, strConfig, adoConnection, adoCommand, strQuery
Dim adoRecordset, objDC, objSite

‘ Determine configuration context from RootDSE object.
Set objRootDSE = GetObject("LDAP://RootDSE")
strConfig = objRootDSE.Get("configurationNamingContext")

‘ Use ADO to search Active Directory for ObjectClass nTDSDSA.
Set adoCommand = CreateObject("ADODB.Command")
Set adoConnection = CreateObject("ADODB.Connection")
adoConnection.Provider = "ADsDSOObject"
adoConnection.Open "Active Directory Provider"
adoCommand.ActiveConnection = adoConnection

strQuery = "<LDAP://" & strConfig _
    & ">;(ObjectClass=nTDSDSA);AdsPath;subtree"

adoCommand.CommandText = strQuery
adoCommand.Properties("Page Size") = 100
adoCommand.Properties("Timeout") = 30
adoCommand.Properties("Cache Results") = False

Set adoRecordset = adoCommand.Execute

‘ The parent object of each object with ObjectClass=nTDSDSA is a Domain
‘ Controller. The parent of each Domain Controller is a "Servers"
‘ container, and the parent of this container is the "Site" container.
Do Until adoRecordset.EOF
    Set objDC = GetObject( _
        GetObject(adoRecordset.Fields("AdsPath").Value).Parent)
    Set objSite = GetObject(GetObject(objDC.Parent).Parent)
    Wscript.Echo "Domain Controller: " & objDC.cn & vbCrLf _
        & "DNS Host Name: " & objDC.DNSHostName & vbCrLf _
        & "Site: " & objSite.name

‘Aici e bucata de cod care se conecteaza la DNS si citeste proprietatile

strComputer =  objDC.cn
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strComputer & _
        "\root\MicrosoftDNS")

Set colItems = objWMIService.ExecQuery("Select * from MicrosoftDNS_Server")

For Each objItem in colItems
   

    Wscript.Echo "Address Answer Limit: " & objItem.AddressAnswerLimit
    Wscript.Echo "Allow Update: " & objItem.AllowUpdate
    Wscript.Echo "Autocache Update: " & objItem.AutoCacheUpdate
    Wscript.Echo "Autoconfig File Zones: " & objItem.AutoConfigFileZones
    Wscript.Echo "Bind Secondaries: " & objItem.BindSecondaries
    Wscript.Echo "Boot Method: " & objItem.BootMethod
    Wscript.Echo "Default Aging State: " & objItem.DefaultAgingState
    Wscript.Echo "Default No-Refresh Interval: " & _
        objItem.DefaultNoRefreshInterval
    Wscript.Echo "Default Refresh Interval: " & objItem.DefaultRefreshInterval
    Wscript.Echo "Disable AutoReverse Zones: " & _
        objItem.DisableAutoReverseZones
    Wscript.Echo "Disjoint Nets: " & objItem.DisjointNets
    Wscript.Echo "Directory Service Available: " & objItem.DsAvailable
    Wscript.Echo "Directory Service Polling Interval: " & _
        objItem.DsPollingInterval
    Wscript.Echo "Directory Service Tombstone Interval: " & _
        objItem.DsTombstoneInterval
    Wscript.Echo "EDNS Cache Timeout: " & objItem.EDnsCacheTimeout
    Wscript.Echo "Enable Directory Partitions: " & _
        objItem.EnableDirectoryPartitions
    Wscript.Echo "Enable DNSSec: " & objItem.EnableDnsSec
    Wscript.Echo "Enable EDNS Probes: " & objItem.EnableEDnsProbes
    Wscript.Echo "Event Log Level: " & objItem.EventLogLevel
    Wscript.Echo "Forward Delegations: " & objItem.ForwardDelegations
    If Not IsNull(objItem.Forwarders) Then
        strForwarders = Join(objItem.Forwarders, ",")
        Wscript.Echo "Forwarders: " & strForwarders
    Else
        Wscript.Echo "Forwarders:"
    End If
    Wscript.Echo "Forwarding Timeout: " & objItem.ForwardingTimeout
    Wscript.Echo "Is Slave: " & objItem.IsSlave
    If Not IsNull(objItem.ListenAddresses) Then
        strListenAddresses = Join(objItem.ListenAddresses, ",")
        Wscript.Echo "Listen Addresses: " & strListenAddresses
    Else
        Wscript.Echo "Listen Addresses:"
    End If
    Wscript.Echo "Local Net Priority: " & objItem.LocalNetPriority
    Wscript.Echo "Logfile Maximum Size: " & objItem.LogFileMaxSize
    Wscript.Echo "Logfile Path: " & objItem.LogFilePath
    If Not IsNull(objItem.LogIPFilterList) Then
        strIPFilter = Join(objItem.LogIPFilterList, ",")
        Wscript.Echo "Log IPFilter List: " & strIPFilter
    Else
        Wscript.Echo "Log IPFilter List:"
    End If
    Wscript.Echo "Log Level: " & objItem.LogLevel
    Wscript.Echo "Loose Wildcarding: " & objItem.LooseWildcarding
    Wscript.Echo "Maximum Cache Time-to-Live: " & objItem.MaxCacheTTL
    Wscript.Echo "Maximum Negative Cache Time-to-Live: " & _
        objItem.MaxNegativeCacheTTL
    Wscript.Echo "Name Check Flag: " & objItem.NameCheckFlag
    Wscript.Echo "No Recursion: " & objItem.NoRecursion
    Wscript.Echo "Recursion Retry: " & objItem.RecursionRetry
    Wscript.Echo "Recursion Timeout: " & objItem.RecursionTimeout
    Wscript.Echo "RoundRobin: " & objItem.RoundRobin
    Wscript.Echo "Rpc Protocol: " & objItem.RpcProtocol
    Wscript.Echo "Scavenging Interval: " & objItem.ScavengingInterval
    Wscript.Echo "Secure Responses: " & objItem.SecureResponses
    Wscript.Echo "Send Port: " & objItem.SendPort
    If Not IsNull(objItem.ServerAddresses) Then
        strServerAddress = Join(objItem.ServerAddresses, ",")
        Wscript.Echo "Server Addresses: " & strServerAddress
    Else
        Wscript.Echo "Server Addresses:"
    End If
    Wscript.Echo "Started: " & objItem.Started
    Wscript.Echo "Start Mode: " & objItem.StartMode
    Wscript.Echo "Strict File Parsing: " & objItem.StrictFileParsing
    Wscript.Echo "Update Options: " & objItem.UpdateOptions
    Wscript.Echo "Version: " & objItem.Version
    Wscript.Echo "Write Authority NS: " & objItem.WriteAuthorityNS
    Wscript.Echo "Xfr Connect Timeout: " & objItem.XfrConnectTimeout
    Wscript.Echo "———————————————————-"
Next

    adoRecordset.MoveNext
Loop
adoRecordset.Close

Richard merge pe varianta cu Option Explicit de asta exista liniile cu Dim, insa a trebuit sa dezactivez asta pentru ca in bucata mea de cod nu am declarat variabilele. Am lasat si commenturile lui pentru a fi ceva mai inteligibil scriptul.

Daca va intereseaza doar “forwarders” puteti sa da-ti remove la restul liniilor de cod.