Create AD users from CSV–VBScript edition

Cu toate ca toata lumea acum se da in vant dupa Powershell si nu mai accepta altceva, eu sunt de parere ca e bine sa folosesti ce stii mai bine. Iar eu de exemplu stiu vbscript mai bine decat Powershell.

O sa revin si cu varianta Powershell, insa azi o sa postez un exemplu de script care citeste o lista de useri dintr-un fisier formatat CSV si ii adauga in Active Directory.

Scriptul seteaza si parola pe userii respectivi si ii si activeaza.

on error resume next

Const ForReading = 1

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile("d:\lista_useri.csv", ForReading)

Do While objTextFile.AtEndOfStream <> True
strLine = objtextFile.ReadLine
If inStr(strLine, ",") Then
    arrUserRecord = split(strLine, ",")
    cnUser = "cn=" & arruserRecord(0)
    SAM = arrUserRecord(1)
    GivenName = arrUserRecord(2)
    surname = arrUserRecord(3)

    Set objOU = GetObject("LDAP://ou=Useri,OU=Test,dc=winadmin,dc=local")
    Set objUser = objOU.Create("User", cnUser)
    objUser.Put "sAMAccountName", SAM
    objUser.Put "givenName", GivenName
    objUser.Put "sn", surname
    objUser.Put "userPrincipalName", SAM
    objUser.SetInfo

    objuser.SetPassword "P@ssw0rd"
    objUser.Put "userAccountControl", 512
    objUser.SetInfo

    Wscript.echo cnUser & "    user account created."

End If
Loop

Dupa cum se vede, merge modificat foarte usor si pot fi adaugate mai multe atribute (prin metoda Put) iar scriptul merge modificat ca sa citeasca parola tot din CSV. Atentie ca e nevoie de doua ori de metoda SetInfo altfel nu o sa reusiti sa activati userul.

PS: Scriptul nu face error handling si are activat si on error resume next, asa ca mare atentie atunci cand importati cantitati mari de date.

3 Responses to “Create AD users from CSV–VBScript edition”

Comment from MILAR
Time August 31, 2011 at 11:23 pm

si acum si-ne si cum ii bagam in ceva gruuri pe fiecare tot asa cu script si care s aia numele grupurilor din csv… ? simplu, usor?
respecte
milar

Comment from admin
Time September 5, 2011 at 6:59 pm

Merg adaugati si in grupuri. Depinde si cum ai informatia despre grupuri si cum vrei sa o adaugi, la useri existenti, la useri noi, sau cum o ai structurata in csv. Pentru mai multe intrebari poti folosi forumul winadmin.